/*
	Copyright 2022 Gabriel Jensen

	This file is part of rgo.

	rgo is free software: you can redistribute it and/or modify it under the terms of the GNU Lesser General Public License as published by the Free Software Foundation, either version 3 of the License, or (at your option) any later version.

	rgo is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more details.

	You should have received a copy of the GNU Lesser General Public License along with rgo. If not, see <https://www.gnu.org/licenses/>. 
*/

#include <rgo.h>

.global rgo_fndbyte

rgo_fndbyte:
	/*
		void const * ptr
		size_t       num
		uint8_t      byte
	*/
#if defined(__i386__)
	/* eax: Address of the current element. */
	movl 0x4(%esp),%eax
	/* ecx: Address of the element after the last element. */
	movl 0x8(%esp),%ecx
	addl %eax,%ecx
	/* edx: Byte value. */
	movb 0xC(%esp),%dl
	/* ebx: Current element. */
	pushl %ebx
.loop:
	cmpl %eax,%ecx
	je .nfnd /* We have went through the entire array without finding the byte. */
	movb (%eax),%bl
	cmpb %bl,%dl
	je .fnd /* We have found the byte. */
	incl %eax
	jmp .loop
.fnd:
	popl %ebx
	subl 0x4(%esp),%eax
	ret
.nfnd:
	popl %ebx
	movl $0xFFFFFFFF,%eax
	ret
#elif defined(__x86_64__)
	/* rax: Address of the current element. */
	movq %rdi,%rax
	/* rsi: Address of the element after the last element. */
	addq %rdi,%rsi
	/* rcx: Current element. */
.loop:
	cmpq %rax,%rsi
	je .nfnd /* We have went through the entire array without finding the byte. */
	movb (%rax),%cl
	cmpb %cl,%dl
	je .fnd /* We have found the byte. */
	incq %rax
	jmp .loop
.fnd:
	subq %rdi,%rax
	ret
.nfnd:
	movq $0xFFFFFFFFFFFFFFFF,%rax
	ret
#endif